Détermination des lois reliant le diamètre du cercle image et le champ de pleine lumière d'un téléscope de type Newton à ses caractéristiques

Recherche d'une expression générale

Diamètre du cercle image : application du théorème de Thalès au montage optique

>   thales1:=dci/x;
thales2:=d/(x+f);
thales3:=a/(x+l);

thales1 := dci/x

thales2 := d/(x+f)

thales3 := a/(x+l)

où d représente le diamètre du miroir primaire, f sa focale, a le petit axe du miroir secondaire, l la distance du foyer du primaire au petit axe du miroir secondaire, dci le diamètre du cercle image et x la distance entre le petit axe du secondaire et le sommet du cône de lumière issu du primaire et dont l'intersection avec le plan focal forme le cercle de pleine lumière ou cercle image (la hauteur de ce cône est donc x+f).

D'après le théorème de Thalès, il y a égalité entre les 3 rapports. On peut donc former plusieurs systèmes équivalents de deux équations non redondantes qui permettent d'accéder à deux inconnues : x et dci. Résolvons l'un de ces systèmes.

>   solution:=solve({thales1=thales2,thales1=thales3},{x,dci});
assign(solution);

solution := {x = -(d*l-a*f)/(d-a), dci = -(d*l-a*f)/(-l+f)}

On retrouve l'expression du diamètre du cercle image citée notamment par Nils Olof Carlin.
On aurait aussi pu prendre {thales1=thales2,thales2=thales3} ou encore {thales3=thales2,thales3=thales1}, ce qui revient bien sûr strictement au même.

Notons qu'on se fout, mais alors royalement, de l'expression de x, mais elle est indispensable pour le calcul qui va suivre.

Champ de pleine lumière : méthode trigonométrique

Prenons le triangle SAF (presque pas fait exprès) formé par le foyer du primaire (point F), le sommet du cône de pleine lumière dont on a parlé plus haut (point S), et un point de la circonférence du miroir primaire (point A). On cherche le champ de pleine lumière cpl qui vaut deux fois l'angle Â.

Traduisons d'abord un résultat classique.

>   RelationAngulaire[0]:=S+cpl/2+F=Pi;

RelationAngulaire[0] := S+1/2*cpl+F = Pi

L'angle F et celui qui intercepte en F un arc de miroir primaire entre son centre et A sont supplémentaires, donc on a, en négligeant la courbure du miroir primaire :

>   RelationAngulaire[1]:=tan(Pi-F)=(d/2)/f;

RelationAngulaire[1] := -tan(F) = 1/2*d/f

L'angle S intercepte le même arc que précédemment, mais en S, donc x millimètres plus loin du primaire que précédemment.

>   RelationAngulaire[2]:=tan(S)=(d/2)/(x+f);

RelationAngulaire[2] := tan(S) = 1/2*d/(-(d*l-a*f)/(d-a)+f)

Résolvons le système résultant de ces 3 équations.

>   solution2:=solve({seq(RelationAngulaire[i],i=0..2)},{cpl,S,F});
assign(solution2);

solution2 := {S = arctan(1/2*(d-a)/(-l+f)), F = -arctan(1/2*d/f), cpl = -2*arctan(1/2*(d-a)/(-l+f))+2*arctan(1/2*d/f)+2*Pi}

On cherche un résultat modulo 2 pi.

>   cpl:=cpl-2*Pi;

cpl := -2*arctan(1/2*(d-a)/(-l+f))+2*arctan(1/2*d/f)

Application numérique

Evaluation numérique du diamètre du cercle image dans une configuration déterminée

>   evalf(subs(d=300,f=1200,l=240,a=82,dci));

27.50000000

Evaluation numérique du champ de pleine lumière dans une configuration déterminée

>   evalf(subs(d=300,f=1200,l=240,a=82,cpl));

.225950072e-1

 Ce qui donne en degrés :

>   evalf(subs(d=300,f=1200,l=240,a=82,180*cpl/Pi));

1.294598550

Le diamètre du cercle image vaut donc 27,5 mm pour un téléscope de type Newton de 300 mm à f/4, avec un miroir secondaire de 82 mm de petit axe et dont l'image par lui du foyer se trouve à 240 mm de l'axe optique. Ce qui donne un champ de pleine lumière de 1,29°.

Etude graphique (enfin des images, youpi !)

Diamètre du cercle image et champ de pleine lumière pour différentes tailles de miroir secondaire (variable a)

>   plot(subs(d=300,f=1200,l=240,dci),a=50..100);
plot(subs(d=300,f=1200,l=240,180*cpl/Pi),a=50..100);

[Maple Plot]

[Maple Plot]

En prenant le point de la droite d'abscisse a = 82 mm, on trouve bien une ordonnée dci = 27,5 mm pour la première courbe et cpl = 1,3° pour la seconde, ce qui confirme l'application numérique (cf. plus haut).

Les valeurs de diamètre de cercle image s'annulent pour a = 60 mm : un dimensionnement de 60 mm pour le petit axe du miroir secondaire correpond à une valeur critique où le cercle image est réduit à un point : le foyer. En-dessous de 60 mm le diamètre du cercle image et le champ de pleine lumière deviennent négatifs, ce qui signifie qu'il n'existe aucun point du plan focal soumis à un éclairement de 100 %. En clair, dans ce cas, un téléscope de diamètre inférieur pourra faire aussi bien.

Diamètre du cercle image et champ de pleine lumière pour différentes valeurs de distance de l'axe optique à l'image du foyer par le miroir secondaire (variable l)

>   plot(subs(d=202,f=1229,a=46,dci),l=150..300);
plot(subs(d=202,f=1229,a=46,180*cpl/Pi),l=150..300);

[Maple Plot]

[Maple Plot]

Exemple de recherche d'une combinaison (a,l) optimale pour un diamètre de cercle image donné (disons 27,26 mm, la taille du capteur CMOS qui équipe les appareils numériques Canon 10D et 300D)

>   plot3d({subs(d=300,f=1200,dci),27.26},a=60..100,l=150..300);

[Maple Plot]

La solution se trouve dans la courbe formée par l'intersection de ces deux surfaces qui, en 2D, donne (j'en profite pour rajouter quelques autres dimensions de diagonale de matrice ou film) :

>   sol:=dia->solve(subs(d=300,f=1200,dci)=dia,l);
plot([sol(0),sol(8.29),sol(17.94),sol(27.26),sol(33.31),sol(34.65),sol(43.27),sol(43.66)],a=60..100,l=150..300,legend=["Valeur critique (cercle image ponctuel)","SBIG ST-7 (8,29 mm)","SBIG ST-10 (17,94 mm)","Canon EOS 10D/300D (27,26 mm)","SBIG STL-6303 (33,31 mm)","SBIG STL-1001 (34,65 mm)","Film 24x36 (43,27 mm)","SBIG STL-11000 (43,66 mm)"]);

sol := proc (dia) options operator, arrow; solve(subs(d = 300,f = 1200,dci) = dia,l) end proc

[Maple Plot]

Ces courbes (en fait des droites), chacune représentant toutes les combinaisons (a,l) possibles pour un diamètre de cercle image donné, mettent bien en évidence la difficulté à trouver le compromis, difficulté qui croît avec la taille du capteur (ou du film). Les gros capteurs étant souvent les plus performants (meilleure résolution et/ou meilleure sensibilité) mais aussi les plus chers, on aura donc tendance à minimiser l (porte-oculaire « low profile » par exemple) et à maximiser a (au détriment de l'obstruction) si on suit la voie de l'imagerie haute performance... et sans vignetage !

N.B.: Il existe d'autres facteurs de vignetage qu'un secondaire trop petit ou trop près du miroir primaire. Citons notamment un porte-oculaire trop petit en diamètre ou un tube trop étroit, celui-ci devant être au moins égal à :

>   DiamètreTubeMini:=subs('cpl'=cpl,d+2*z*tan('cpl'/2));

`DiamètreTubeMini` := d+2*z*tan(-arctan(1/2*(d-a)/(-l+f))+arctan(1/2*d/f))

où z désigne la distance de la section de tube considérée au miroir primaire (les tubes étant en général cylindriques, on fera dans la majorité des cas le calcul avec la donnée de la distance du miroir à l'extrémité du tube correspondant à l'ouverture).

L'application numérique pour l'extrémité du tube située par exemple à z = 1100 mm donne :

>   evalf(subs(d=300,f=1200,l=240,a=82,z=1100,DiamètreTubeMini));

324.8555654

Annexe : simplification par développement limité

Les angles A, S et cpl étant proches de 0 et F proche de pi, on peut effectuer le calcul du champ de pleine lumière en s'affranchissant des termes en arctangente. Pour ce faire, on effectue des développements limités au second ordre.
Reprenons notre démarche depuis le début

Prenons le triangle SAF (presque pas fait exprès) formé par le foyer du primaire (point F), le sommet du cône de pleine lumière dont on a parlé plus haut (point S), et un point de la circonférence du miroir primaire (point A). On cherche le champ de pleine lumière cpl qui vaut deux fois l'angle Â.

Traduisons d'abord un résultat classique.

>   RelationAngulaireDL[0]:=SDL+cplDL/2+FDL=Pi;

RelationAngulaireDL[0] := SDL+1/2*cplDL+FDL = Pi

L'angle F et celui qui intercepte en F un arc de miroir primaire entre son centre et A sont supplémentaires, donc on a, en négligeant la courbure du miroir primaire :

>   RelationAngulaireDL[1]:=convert(series(tan(Pi-FDL),FDL=Pi,2),polynom)=(d/2)/f;

RelationAngulaireDL[1] := Pi-FDL = 1/2*d/f

L'angle S intercepte le même arc que précédemment, mais en S, donc x millimètres plus loin du primaire que précédemment.

>   RelationAngulaireDL[2]:=convert(series(tan(SDL),SDL=0,2),polynom)=(d/2)/(x+f);

RelationAngulaireDL[2] := SDL = 1/2*d/(-(d*l-a*f)/(d-a)+f)

Notons que l'emploi de la fonction « series » effectue un développement limité qui permet de se débarasser des termes en arctangente (les angles A, S et cpl sont proches de 0 et F est proche de pi radians). On aura ainsi une expression moins précise mais plus simple pour cpl.

Résolvons le système résultant de ces 3 équations.

>   solution2DL:=solve({seq(RelationAngulaireDL[i],i=0..2)},{cplDL,SDL,FDL});
assign(solution2DL);

solution2DL := {cplDL = -(d*l-a*f)/(-l+f)/f, SDL = 1/2*(d-a)/(-l+f), FDL = 1/2*(2*Pi*f-d)/f}

On remarque qu'il suffit dans l'approximation qui a été faite de diviser le diamètre du cercle image par la distance focale pour obtenir (en radians) le champ de pleine lumière.

Evaluation numérique du champ de pleine lumière dans une configuration déterminée

>   evalf(subs(d=300,f=1200,l=240,a=82,cplDL));

.2291666667e-1

 Ce qui donne en degrés :

>   evalf(subs(d=300,f=1200,l=240,a=82,180*cplDL/Pi));

1.313028280

Comparons l'erreur en pour cent par rapport au résultat précédent.

>   epsilon1:=evalf((subs(d=300,f=1200,l=240,a=82,cplDL)/subs(d=300,f=1200,l=240,a=82,cpl)-1)*100);

epsilon1 := 1.4235865

L'erreur est donc de 1,42 % (par excès), ce qui est tout à fait acceptable.

Dans la foulée, on peut en profiter pour simplifier également la fomule du diamètre minimal du tube :

>   DiamètreTubeMiniDL:=subs('cpl'=cplDL,convert(series(d+2*z*tan('cpl'/2),'cpl'=0,2),polynom));

`DiamètreTubeMiniDL` := d-z*(d*l-a*f)/(-l+f)/f

La même application numérique que précédemment nous donne :

>   evalf(subs(d=300,f=1200,l=240,a=82,z=1100,DiamètreTubeMiniDL));

325.2083333

Avec une erreur :

>   epsilon2:=evalf((subs(d=300,f=1200,l=240,a=82,z=1100,DiamètreTubeMiniDL)/subs(d=300,f=1200,l=240,a=82,z=1100,DiamètreTubeMini)-1)*100);

epsilon2 := .1085922

L'erreur est ridicule puisqu'elle vaut environ un pour mille. Plus qu'acceptable.

Récapitulatif

A toutes fins utiles, rappelons rapidement les résultats fondamentaux trouvés au cours de notre périple.

Diamètre du cercle image (dci) en fonction du diamètre du miroir primaire (d), de sa focale (f), du petit axe du miroir secondaire (a) et de la distance entre le foyer et le centre du miroir secondaire (l) :

>   'dci'=dci;

dci = -(d*l-a*f)/(-l+f)

Champ de pleine lumière (cpl) en radians en fonction des mêmes paramètres :

>   'cpl'='dci'/f;
'cpl'=cplDL;

cpl = dci/f

cpl = -(d*l-a*f)/(-l+f)/f

Idem, mais en degrés :

>   'cpl'=180*'dci'/f/Pi;
'cpl'=180*cplDL/Pi;

cpl = 180*dci/f/Pi

cpl = -180*(d*l-a*f)/(-l+f)/f/Pi

Distance entre le foyer et le centre du miroir secondaire (l) en fonction du diamètre de cercle image voulu (dci) :

>   'l'=solve('dci'=dci,l);

l = f*(dci-a)/(dci-d)

Distance entre le foyer et le centre du miroir secondaire (l) en fonction du champ de pleine lumière voulu (cpl) en degrés :

>   'l'=solve('cpl'=180*cplDL/Pi,l);

l = f*(cpl*Pi*f-180*a)/(cpl*Pi*f-180*d)

Diamètre minimal du tube à une distance z donnée du miroir primaire en fonction des différents paramètres du téléscope (cpl sera exprimé en degrés) :

>   'DiamètreTubeMini'=d+z*'cpl'*Pi/180;
'DiamètreTubeMini'=d+z*'dci'/f;
'DiamètreTubeMini'=d+z*cplDL;

`DiamètreTubeMini` = d+1/180*z*cpl*Pi

`DiamètreTubeMini` = d+z*dci/f

`DiamètreTubeMini` = d-z*(d*l-a*f)/(-l+f)/f